You cannot select more than 25 topics
Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
76 lines
3.9 KiB
Solidity
76 lines
3.9 KiB
Solidity
// SPDX-License-Identifier: MIT
|
|
// OpenZeppelin Contracts (last updated v4.8.0) (utils/Create2.sol)
|
|
|
|
pragma solidity ^0.8.0;
|
|
|
|
/**
|
|
* @dev Helper to make usage of the `CREATE2` EVM opcode easier and safer.
|
|
* `CREATE2` can be used to compute in advance the address where a smart
|
|
* contract will be deployed, which allows for interesting new mechanisms known
|
|
* as 'counterfactual interactions'.
|
|
*
|
|
* See the https://eips.ethereum.org/EIPS/eip-1014#motivation[EIP] for more
|
|
* information.
|
|
*/
|
|
library Create2 {
|
|
/**
|
|
* @dev Deploys a contract using `CREATE2`. The address where the contract
|
|
* will be deployed can be known in advance via {computeAddress}.
|
|
*
|
|
* The bytecode for a contract can be obtained from Solidity with
|
|
* `type(contractName).creationCode`.
|
|
*
|
|
* Requirements:
|
|
*
|
|
* - `bytecode` must not be empty.
|
|
* - `salt` must have not been used for `bytecode` already.
|
|
* - the factory must have a balance of at least `amount`.
|
|
* - if `amount` is non-zero, `bytecode` must have a `payable` constructor.
|
|
*/
|
|
function deploy(uint256 amount, bytes32 salt, bytes memory bytecode) internal returns (address addr) {
|
|
require(address(this).balance >= amount, "Create2: insufficient balance");
|
|
require(bytecode.length != 0, "Create2: bytecode length is zero");
|
|
/// @solidity memory-safe-assembly
|
|
assembly {
|
|
addr := create2(amount, add(bytecode, 0x20), mload(bytecode), salt)
|
|
}
|
|
require(addr != address(0), "Create2: Failed on deploy");
|
|
}
|
|
|
|
/**
|
|
* @dev Returns the address where a contract will be stored if deployed via {deploy}. Any change in the
|
|
* `bytecodeHash` or `salt` will result in a new destination address.
|
|
*/
|
|
function computeAddress(bytes32 salt, bytes32 bytecodeHash) internal view returns (address) {
|
|
return computeAddress(salt, bytecodeHash, address(this));
|
|
}
|
|
|
|
/**
|
|
* @dev Returns the address where a contract will be stored if deployed via {deploy} from a contract located at
|
|
* `deployer`. If `deployer` is this contract's address, returns the same value as {computeAddress}.
|
|
*/
|
|
function computeAddress(bytes32 salt, bytes32 bytecodeHash, address deployer) internal pure returns (address addr) {
|
|
/// @solidity memory-safe-assembly
|
|
assembly {
|
|
let ptr := mload(0x40) // Get free memory pointer
|
|
|
|
// | | ↓ ptr ... ↓ ptr + 0x0B (start) ... ↓ ptr + 0x20 ... ↓ ptr + 0x40 ... |
|
|
// |-------------------|---------------------------------------------------------------------------|
|
|
// | bytecodeHash | CCCCCCCCCCCCC...CC |
|
|
// | salt | BBBBBBBBBBBBB...BB |
|
|
// | deployer | 000000...0000AAAAAAAAAAAAAAAAAAA...AA |
|
|
// | 0xFF | FF |
|
|
// |-------------------|---------------------------------------------------------------------------|
|
|
// | memory | 000000...00FFAAAAAAAAAAAAAAAAAAA...AABBBBBBBBBBBBB...BBCCCCCCCCCCCCC...CC |
|
|
// | keccak(start, 85) | ↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑↑ |
|
|
|
|
mstore(add(ptr, 0x40), bytecodeHash)
|
|
mstore(add(ptr, 0x20), salt)
|
|
mstore(ptr, deployer) // Right-aligned with 12 preceding garbage bytes
|
|
let start := add(ptr, 0x0b) // The hashed data starts at the final garbage byte which we will set to 0xff
|
|
mstore8(start, 0xff)
|
|
addr := keccak256(start, 85)
|
|
}
|
|
}
|
|
}
|