You cannot select more than 25 topics
Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
120 lines
4.3 KiB
Solidity
120 lines
4.3 KiB
Solidity
// SPDX-License-Identifier: MIT
|
|
// OpenZeppelin Contracts (last updated v4.8.0) (governance/extensions/GovernorVotesQuorumFraction.sol)
|
|
|
|
pragma solidity ^0.8.0;
|
|
|
|
import "./GovernorVotes.sol";
|
|
import "../../utils/Checkpoints.sol";
|
|
import "../../utils/math/SafeCast.sol";
|
|
|
|
/**
|
|
* @dev Extension of {Governor} for voting weight extraction from an {ERC20Votes} token and a quorum expressed as a
|
|
* fraction of the total supply.
|
|
*
|
|
* _Available since v4.3._
|
|
*/
|
|
abstract contract GovernorVotesQuorumFraction is GovernorVotes {
|
|
using Checkpoints for Checkpoints.History;
|
|
|
|
uint256 private _quorumNumerator; // DEPRECATED
|
|
Checkpoints.History private _quorumNumeratorHistory;
|
|
|
|
event QuorumNumeratorUpdated(uint256 oldQuorumNumerator, uint256 newQuorumNumerator);
|
|
|
|
/**
|
|
* @dev Initialize quorum as a fraction of the token's total supply.
|
|
*
|
|
* The fraction is specified as `numerator / denominator`. By default the denominator is 100, so quorum is
|
|
* specified as a percent: a numerator of 10 corresponds to quorum being 10% of total supply. The denominator can be
|
|
* customized by overriding {quorumDenominator}.
|
|
*/
|
|
constructor(uint256 quorumNumeratorValue) {
|
|
_updateQuorumNumerator(quorumNumeratorValue);
|
|
}
|
|
|
|
/**
|
|
* @dev Returns the current quorum numerator. See {quorumDenominator}.
|
|
*/
|
|
function quorumNumerator() public view virtual returns (uint256) {
|
|
return _quorumNumeratorHistory._checkpoints.length == 0 ? _quorumNumerator : _quorumNumeratorHistory.latest();
|
|
}
|
|
|
|
/**
|
|
* @dev Returns the quorum numerator at a specific block number. See {quorumDenominator}.
|
|
*/
|
|
function quorumNumerator(uint256 blockNumber) public view virtual returns (uint256) {
|
|
// If history is empty, fallback to old storage
|
|
uint256 length = _quorumNumeratorHistory._checkpoints.length;
|
|
if (length == 0) {
|
|
return _quorumNumerator;
|
|
}
|
|
|
|
// Optimistic search, check the latest checkpoint
|
|
Checkpoints.Checkpoint memory latest = _quorumNumeratorHistory._checkpoints[length - 1];
|
|
if (latest._blockNumber <= blockNumber) {
|
|
return latest._value;
|
|
}
|
|
|
|
// Otherwise, do the binary search
|
|
return _quorumNumeratorHistory.getAtBlock(blockNumber);
|
|
}
|
|
|
|
/**
|
|
* @dev Returns the quorum denominator. Defaults to 100, but may be overridden.
|
|
*/
|
|
function quorumDenominator() public view virtual returns (uint256) {
|
|
return 100;
|
|
}
|
|
|
|
/**
|
|
* @dev Returns the quorum for a block number, in terms of number of votes: `supply * numerator / denominator`.
|
|
*/
|
|
function quorum(uint256 blockNumber) public view virtual override returns (uint256) {
|
|
return (token.getPastTotalSupply(blockNumber) * quorumNumerator(blockNumber)) / quorumDenominator();
|
|
}
|
|
|
|
/**
|
|
* @dev Changes the quorum numerator.
|
|
*
|
|
* Emits a {QuorumNumeratorUpdated} event.
|
|
*
|
|
* Requirements:
|
|
*
|
|
* - Must be called through a governance proposal.
|
|
* - New numerator must be smaller or equal to the denominator.
|
|
*/
|
|
function updateQuorumNumerator(uint256 newQuorumNumerator) external virtual onlyGovernance {
|
|
_updateQuorumNumerator(newQuorumNumerator);
|
|
}
|
|
|
|
/**
|
|
* @dev Changes the quorum numerator.
|
|
*
|
|
* Emits a {QuorumNumeratorUpdated} event.
|
|
*
|
|
* Requirements:
|
|
*
|
|
* - New numerator must be smaller or equal to the denominator.
|
|
*/
|
|
function _updateQuorumNumerator(uint256 newQuorumNumerator) internal virtual {
|
|
require(
|
|
newQuorumNumerator <= quorumDenominator(),
|
|
"GovernorVotesQuorumFraction: quorumNumerator over quorumDenominator"
|
|
);
|
|
|
|
uint256 oldQuorumNumerator = quorumNumerator();
|
|
|
|
// Make sure we keep track of the original numerator in contracts upgraded from a version without checkpoints.
|
|
if (oldQuorumNumerator != 0 && _quorumNumeratorHistory._checkpoints.length == 0) {
|
|
_quorumNumeratorHistory._checkpoints.push(
|
|
Checkpoints.Checkpoint({_blockNumber: 0, _value: SafeCast.toUint224(oldQuorumNumerator)})
|
|
);
|
|
}
|
|
|
|
// Set new quorum for future proposals
|
|
_quorumNumeratorHistory.push(newQuorumNumerator);
|
|
|
|
emit QuorumNumeratorUpdated(oldQuorumNumerator, newQuorumNumerator);
|
|
}
|
|
}
|